Autopilot events in manual correct? VS Mode?

Rhinozherous

It seems we have to also assign and use the "K:AP_MASTER" button... it is kind of weird because the aircraft has no AP Master button. To be able to select HDG mode for example I have to first press the assigned AP MASTER and after this it lets me select assigned HDG, NAV,...

Rhinozherous

@Black-Square Is the fact that we have to use the AP Master a workaround because of MSFS or is this something that will change?
I just want to know, sorry to bother you! Thank you very much!

MatzeH84

I currently solved it in mobiflight with RPN code. It first checks if the AP Master is on, if not, activates it, and then selects HDG mode. Same for all other modes.
Additionally, when using the suggested AP disconnect variable, you actually have to press twice to cancel the mode- because it behaves like it does in the Bo/Baron/Duke where you disengage the AP with the first click, but keep the FD modes active which are only canceled on the second click.
As far as I understand, in the 114 the disconnect button should cancel the AP and all modes immediately, as there is no FD installed.

SadBucket

@MatzeH84 was going to suggest that work around.

@Rhinozherous I believe it is safe to assume its an MSFS limitation.

Rhinozherous

@MatzeH84 Thank you, I will trie the same with Axis and Ohs I think. As I have not much of a clue of programming I will see what chatGPT can do for me

Woolies

It’s funny, I am actually using virtually no bindings for the 114 for a change. I did go and set most up but kinda enjoying using the mouse for a change. Also I don’t know how to trigger button press sounds from the aircraft, if at all possible, and that is more a lack of immersion than anything else.

fredgarven

I spent some time going through the Commander 114’s actual model behavior with the MSFS DevMode Behavior Viewer and now have the autopilot buttons working correctly through MobiFlight.

The missing piece is that the cockpit buttons do more than send the basic mode event. They first check that the autopilot is powered and, when necessary, automatically turn on AP_MASTER. That is why assigning only the individual events from the manual can make it seem like a separate AP Master button is required.

These are RPN calculator codes. In MobiFlight, use each one as On Press and leave On Release blank. The same RPN logic should also be usable as an AxisAndOhs script.

HDG

(A:CIRCUIT ON:54, bool)
(L:var_AutopilotTest, bool) !
and
if{
    (A:AUTOPILOT MASTER, bool) !
    if{
        (>K:AP_MASTER)
    }

    (>K:AP_PANEL_HEADING_HOLD)
}

NAV

(A:CIRCUIT ON:54, bool)
(L:var_AutopilotTest, bool) !
and
if{
    (A:AUTOPILOT MASTER, bool) !
    if{
        (>K:AP_MASTER)
    }

    (>K:AP_NAV1_HOLD)
}

Back Course

(A:CIRCUIT ON:54, bool)
(L:var_AutopilotTest, bool) !
and
if{
    (A:AUTOPILOT MASTER, bool) !
    if{
        (>K:AP_MASTER)
    }

    (>K:AP_BC_HOLD)
}

Vertical Speed

The VS button is more involved because it transfers the Commander’s selected altitude and selected vertical speed into the simulator autopilot before engaging VS mode.

(A:CIRCUIT ON:54, bool)
(L:var_AutopilotTest, bool) !
and
if{
    0 (>L:var_AutopilotVsIntervention, bool)

    (L:var_PreselectedAltitude, number)
    1 r (>K:2:AP_ALT_VAR_SET_ENGLISH)

    (L:var_PreselectedVerticalSpeed, number) 100 *
    1 r (>K:2:AP_VS_VAR_SET_ENGLISH)

    (A:AUTOPILOT MASTER, bool) !
    if{
        (>K:AP_MASTER)
    }

    (>K:AP_VS_HOLD)
}

The Commander stores the selected vertical speed in hundreds of feet per minute, which is why the script multiplies it by 100.

ALT

(A:CIRCUIT ON:54, bool)
(L:var_AutopilotTest, bool) !
and
if{
    0 (>L:var_AutopilotAltIntervention, bool)

    (L:PMS50_APGA_RUNNING, bool)
    if{
        (L:PMS50_APGA_ACTIVE_VERTICAL_MODE, number) 3 ==
    }
    els{
        (A:AUTOPILOT ALTITUDE LOCK, bool)
    }

    if{
        (A:AUTOPILOT MASTER, bool) !
        if{
            (>K:AP_MASTER)
        }

        (>K:AP_PITCH_LEVELER_ON)
    }
    els{
        (A:AUTOPILOT MASTER, bool) !
        if{
            (>K:AP_MASTER)
        }

        (>K:AP_ALT_HOLD)
    }
}

This duplicates the airplane’s ALT-button logic rather than merely sending a generic altitude-hold event.

AP Disconnect - cancel everything with one press

The reason the suggested disconnect assignment requires two presses is that the Commander’s cockpit behavior uses an if/else arrangement:

First press disconnects the autopilot.
A later press cancels the remaining flight-director modes.

For a hardware disconnect button, this version checks and cancels both during the same press:

(A:AUTOPILOT MASTER, bool)
if{
    (>K:AP_MASTER)
}

(A:AUTOPILOT FLIGHT DIRECTOR ACTIVE, bool)
if{
    (>K:TOGGLE_FLIGHT_DIRECTOR)
}

That gives the expected Commander behavior: one press disconnects the autopilot and removes the remaining active modes.

Rhinozherous

@fredgarven Thank you a lot! Will trie it asap in AAOhs.

MatzeH84

Yeah, ChatGPT or Gemini save the day. It has become really easy once you figured out the correct variables.

Rhinozherous

@fredgarven Your scripts worked like a charm, thank you again!